home *** CD-ROM | disk | FTP | other *** search
/ Shareware Grab Bag / Shareware Grab Bag.iso / 010 / pcgames.arc / BOMB.BAS < prev    next >
BASIC Source File  |  1982-12-28  |  3KB  |  72 lines
  1. 100 CLS
  2. 110 A$=STRING$(80,205)
  3. 120 PRINT A$
  4. 130 PRINT TAB(34)"FIND THE BOMB"
  5. 140 COLOR 23,0,0
  6. 150 PRINT :PRINT :PRINT TAB(39)"IPCO"
  7. 160 COLOR 7,0,0
  8. 170 PRINT :PRINT :PRINT TAB(25)"PERSONAL COMPUTER OWNERS GROUP"
  9. 180 PRINT :PRINT :PRINT TAB(19)"P.O. BOX 10426, PITTSBURGH, PENNSYLVANIA 15234"
  10. 190 PRINT A$
  11. 200 PRINT :PRINT :PRINT :PRINT :PRINT
  12. 210 PRINT TAB(28)"PRESS ANY KEY TO CONTINUE"
  13. 220 A$=INKEY$:IF A$="" THEN 220
  14. 230 CLS
  15. 240 CLS:LOCATE 4,28:PRINT "DEFUSE"
  16. 250 LOCATE 9,20:PRINT"";:INPUT "DO YOU NEED INSTRUCTIONS";I$
  17. 260 IF LEFT$(I$,1)="N" THEN CLS: GOTO 360
  18. 270 CLS: PRINT TAB(29);"DEFUSE":PRINT
  19. 280 PRINT"YOU ARE IN A GOVERNMENT EXPERIMENTAL BUILDING WITH"
  20. 290 PRINT "1,000,000 ROOMS IN IT.  THE BUILDING IS 100 ROOMS"
  21. 300 PRINT "LONG (0-99),100 ROOMS WIDE (0-99), AND 100 ROOMS HIGH (0-99).
  22. 310 PRINT: PRINT"IN IT A BOMB IS HIDDEN.  THE BOMB SENDS OUT SIGNALS THAT"
  23. 320 PRINT "GET STRONGER AS YOU GET CLOSER.  YOU HAVE 200 SECONDS"
  24. 330 PRINT "TO DEACTIVATE IT."
  25. 340 LOCATE 12,20:PRINT "PRESS ANY KEY TO CONTINUE."
  26. 350 IF INKEY$=""THEN 350 ELSE CLS
  27. 360 A=INT(100*RND(8)): B=INT(100*RND(3))
  28. 370 C=INT(100*RND(0)):IF A >0 THEN 400
  29. 380 IF B>0 THEN 400
  30. 390 IF C=0 THEN 370
  31. 400 D=0:E=0:F=0:G=0:LOCATE 2,13:PRINT "";:GOSUB 410:GOTO 470
  32. 410 LB=PEEK(16416): HB=PEEK(16417):PRINT CHR$(28):
  33. 420 PRINT"SIGNAL";TAB(15);"L";TAB(20);"W";TAB(25);"H";
  34. 430 PRINT TAB(35);"SEC";TAB(45);"COORDINATES (L,W,H)"
  35. 440 PRINT "-------";TAB(14);"---";TAB(19);"---";TAB(24);"---";
  36. 450 PRINT TAB(34);"-----";TAB(44)"----------------"
  37. 460 POKE 16416,LB:POKE 16417,HB:RETURN
  38. 470 REM
  39. 480 IM$="####.##    ###  ###  ###        ###"
  40. 490 SI=10000-ABS((A/100+B+C*100)-(D/100+E+F*100))
  41. 500 PRINT USING IM$;SI,D,E,F,G;:PRINT TAB(45);
  42. 510 INPUT D,E,F:G=G+10:IF A<>D THEN 540
  43. 520 IF B<>E THEN 540
  44. 530 IF C=F THEN 610
  45. 540 IF G=200 THEN 560
  46. 550 GOTO 620
  47. 560 CLS:PRINT "BOOOOOOMMM!!!":PRINT "YOU BLEW IT.  THE BUILDING BLEW UP!"
  48. 570 PRINT"THE BOMB WAS LOCATED AT THE COORDINATES (L,W,H):";A;B;C
  49. 580 PRINT:PRINT: PRINT "WANT TO PLAY AGAIN";
  50. 590 INPUT Z$: IF LEFT$(Z$,1)="Y" THEN CLS: GOTO 360
  51. 600 GOTO 790
  52. 610 CLS: PRINT "BOMB DEACTIVATED AT";G;"SECONDS!!!!": GOTO 580
  53. 620 IF D>99 THEN 690
  54. 630 IF D<0 THEN 690
  55. 640 IF E>99 THEN 690
  56. 650 IF E<0 THEN 690
  57. 660 IF F>99 THEN 730
  58. 670 IF F<0 THEN 740
  59. 680 GOTO 470
  60. 690 CLS: PRINT "YOU WALKED OUT A WINDOW ON THE ";: IF F<4 THEN 750
  61. 700 PRINT F;"TH FLOOR!!!"
  62. 710 PRINT "YOU WERE KILLED AND";200-G;"SECONDS LATER THE BUILDING"
  63. 720 PRINT "BLEW UP!!!": GOTO 580
  64. 730 CLS: PRINT "YOU ARE NOW";F*9;"FEET IN THE AIR!!!": GOTO 710
  65. 740 CLS:PRINT"YOU ARE NOW";-1*(F*9);"FEET UNDERGROUND!!!": GOTO 710
  66. 750 ON F GOTO 760,770,780
  67. 760 PRINT "1ST FLOOR!!!":GOTO 710
  68. 770 PRINT "2ND FLOOR!!!":GOTO 710
  69. 780 PRINT "3RD FLOOR!!!":GOTO 710
  70. 790 END
  71.  
  72.